Développeur PHP/Zend/Typo3 - Administrateur Linux | PIPRIME.FR : Official Gallery One-Pager

Official Asymptote example – secondaryaxis

Category: Asymptote,Official Gallery One-Pager — Ph. Ivaldi @ 1 h 57 min

You may view all the posts of the category "Official Gallery One-Pager"



(Compiled with Asymptote version 2.14svn-r5318)

/* This code comes from The Official Asymptote Gallery */
    
import graph;

size(9cm,6cm,IgnoreAspect);
string data="secondaryaxis.csv";

file in=input(data).line().csv();

string[] titlelabel=in;
string[] columnlabel=in;

real[][] a=in.dimension(0,0);
a=transpose(a);
real[] t=a[0], susceptible=a[1], infectious=a[2], dead=a[3], larvae=a[4];
real[] susceptibleM=a[5], exposed=a[6],infectiousM=a[7];

scale(true);

draw(graph(t,susceptible,t >= 10 & t <= 15));
draw(graph(t,dead,t >= 10 & t <= 15),dashed);

xaxis("Time ($\tau$)",BottomTop,LeftTicks);
yaxis(Left,RightTicks);

picture secondary=secondaryY(new void(picture pic) {
    scale(pic,Linear(true),Log(true));
    draw(pic,graph(pic,t,infectious,t >= 10 & t <= 15),red);
    yaxis(pic,Right,red,LeftTicks(begin=false,end=false));
  });
                             
add(secondary);
label(shift(5mm*N)*"Proportion of crows",point(NW),E);

Mots-clefs : array, Axis, Data, Graph, picture

Comments (0)

Official Asymptote example – scaledgraph

Category: Asymptote,Official Gallery One-Pager — Ph. Ivaldi @ 12 h 57 min

You may view all the posts of the category "Official Gallery One-Pager"



(Compiled with Asymptote version 2.14svn-r5318)

/* This code comes from The Official Asymptote Gallery */
    
import graph;

axiscoverage=0.9;
size(200,IgnoreAspect);

real[] x={-1e-11,1e-11};
real[] y={0,1e6};

real xscale=round(log10(max(x)));
real yscale=round(log10(max(y)))-1;

draw(graph(x*10^(-xscale),y*10^(-yscale)),red);

xaxis("$x/10^{"+(string) xscale+"}$",BottomTop,LeftTicks);
yaxis("$y/10^{"+(string) yscale+"}$",LeftRight,RightTicks(trailingzero));

Mots-clefs : Axis, Graph

Comments (0)

Official Asymptote example – saddle

Category: Asymptote,Official Gallery One-Pager — Ph. Ivaldi @ 11 h 57 min

You may view all the posts of the category "Official Gallery One-Pager"



(Compiled with Asymptote version 2.14svn-r5318)

/* This code comes from The Official Asymptote Gallery */
    
import three;

size(100,0);
path3 g=(1,0,0)..(0,1,1)..(-1,0,0)..(0,-1,1)..cycle;
draw(g);
draw(((-1,-1,0)--(1,-1,0)--(1,1,0)--(-1,1,0)--cycle));
dot(g,red);

Mots-clefs : Basis, draw (3D), path3, Point/Dot

Comments (0)

Official Asymptote example – sacylinder3D

Category: Asymptote,Official Gallery One-Pager — Ph. Ivaldi @ 10 h 57 min

You may view all the posts of the category "Official Gallery One-Pager"



(Compiled with Asymptote version 2.14svn-r5318)

/* This code comes from The Official Asymptote Gallery */
    
import solids;
size(0,100);

real r=1;
real h=3;

revolution R=cylinder(-h/2*Z,r,h);
draw(surface(R),lightgreen+opacity(0.5),render(compression=Low));
draw((0,0,-h/2)--(0,0,h/2),dashed);
dot((0,0,-h/2));
dot((0,0,h/2));
draw("$L$",(0,r,-h/2)--(0,r,h/2),W,black);
draw("$r$",(0,0,-h/2)--(0,r,-h/2),red);
draw(arc(O,1,90,90,90,0),red,Arrow3);

Mots-clefs : arc (3D), Revolution, Solid, surface

Comments (0)

Official Asymptote example – sacylinder

Category: Asymptote,Official Gallery One-Pager — Ph. Ivaldi @ 9 h 57 min

You may view all the posts of the category "Official Gallery One-Pager"



(Compiled with Asymptote version 2.14svn-r5318)

/* This code comes from The Official Asymptote Gallery */
    
import graph;
size(0,100);

real r=1;
real h=3;

yaxis(dashed);

real m=0.475*h;

draw((r,0)--(r,h));
label("$L$",(r,0.5*h),E);

real s=4;

pair z1=(s,0);
pair z2=z1+(2*pi*r,h);
filldraw(box(z1,z2),lightgreen);
pair zm=0.5*(z1+z2);
label("$L$",(z1.x,zm.y),W);
label("$2\pi r$",(zm.x,z2.y),N);
draw("$r$",(0,m)--(r,m),N,red,Arrows);

draw((0,1.015h),yscale(0.5)*arc(0,0.25cm,-250,70),red,ArcArrow);

Comments (0)

Official Asymptote example – sacone3D

Category: Asymptote,Official Gallery One-Pager — Ph. Ivaldi @ 8 h 57 min

You may view all the posts of the category "Official Gallery One-Pager"



(Compiled with Asymptote version 2.14svn-r5318)

/* This code comes from The Official Asymptote Gallery */
    
import solids;

size(0,75);
real r=1;
real h=1;

revolution R=cone(r,h);

draw(surface(R),lightgreen+opacity(0.5),render(compression=Low));
pen edge=blue+0.25mm;
draw("$\ell$",(0,r,0)--(0,0,h),W,edge);
draw("$r$",(0,0,0)--(r,0,0),red+dashed);
draw((0,0,0)--(0,0,h),red+dashed);
dot(h*Z);

Mots-clefs : Revolution, Solid, surface

Comments (0)

Official Asymptote example – sacone

Category: Asymptote,Official Gallery One-Pager — Ph. Ivaldi @ 7 h 57 min

You may view all the posts of the category "Official Gallery One-Pager"



(Compiled with Asymptote version 2.14svn-r5318)

/* This code comes from The Official Asymptote Gallery */
    
size(0,150);

pair z0=(0,0);
real r=1;
real h=1;
real l=sqrt(r^2+h^2);
real a=(1-r/l)*360;
real a1=a/2;
real a2=360-a/2;
path g=arc(z0,r,a1,a2);
fill((0,0)--g--cycle,lightgreen);
draw(g);
pair z1=point(g,0);
pair z2=point(g,length(g));

real r2=1.1*r;
path c=arc(0,r2,a1,a2);
draw("$2\pi r$",c,red,Arrows,Bars,PenMargins);
pen edge=blue+0.5mm;
draw("$\ell$",z0--z1,0.5*SE,edge);
draw(z0--z2,edge);
draw(arc(z0,r,a2-360,a1),grey+dashed);
dot(0);

Mots-clefs : arc

Comments (0)

Official Asymptote example – roundpath

Category: Asymptote,Official Gallery One-Pager — Ph. Ivaldi @ 6 h 57 min

You may view all the posts of the category "Official Gallery One-Pager"



(Compiled with Asymptote version 2.14svn-r5318)

/* This code comes from The Official Asymptote Gallery */
    
// example file for 'roundedpath.asy'
// written by stefan knorr

// import needed packages
import roundedpath;

// define open and closed path
path A = (0,0)--(10,10)--(30,10)--(20,0)--(30,-10)--(10,-10);
path B = A--cycle;

draw(shift(-60,0)*A, green);
draw(shift(-30,0)*roundedpath(A,1), red);

// draw open path and some modifications
for (int i = 1; i < 20; ++i)
  draw(roundedpath(A,i/4), rgb(1 - i*0.049, 0, i*0.049) + linewidth(0.5));

draw(shift(-60,-30)*B, green);
draw(shift(-30,-30)*roundedpath(B,1), red);

//draw closed path and some modifications
for (int i = 1; i < 20; ++i)                          // only round edges
  draw(shift(0,-30)*roundedpath(B,i/4), rgb(0.5, i*0.049,0) + linewidth(0.5));

for (int i = 1; i < 20; ++i)                          // round edged and scale 
  draw(shift(0,-60)*roundedpath(B,i/4,1-i/50), rgb(1, 1 - i*0.049,i*0.049) + linewidth(0.5));

for (int i = 1; i < 50; ++i)                          // shift (round edged und scaled shifted version)
  draw(shift(-30,-60)*shift(10,0)*roundedpath(shift(-10,0)*B,i/10,1-i/80), rgb( i*0.024, 1 - i*0.024,0) + linewidth(0.5));

for (int i = 1; i < 20; ++i)                          // shift (round edged und scaled shifted version)
  draw(shift(-60,-60)*shift(10,0)*roundedpath(shift(-10,0)*B,i/4,1-i/50), gray(i/40));

Mots-clefs : path, roundedpath

Comments (0)

Official Asymptote example – roll

Category: Asymptote,Official Gallery One-Pager — Ph. Ivaldi @ 5 h 57 min

You may view all the posts of the category "Official Gallery One-Pager"



(Compiled with Asymptote version 2.14svn-r5318)

/* This code comes from The Official Asymptote Gallery */
    
import graph3;

size(200,0);

triple f(pair t) {
return(t.x+t.y/4+sin(t.y),cos(t.y),sin(t.y));
}

surface s=surface(f,(0,0),(2pi,2pi),7,20,Spline);
draw(s,olive,render(merge=true));

Mots-clefs : Basis, Graph (3D), surface

Comments (0)

Official Asymptote example – ring

Category: Asymptote,Official Gallery One-Pager — Ph. Ivaldi @ 4 h 57 min

You may view all the posts of the category "Official Gallery One-Pager"



(Compiled with Asymptote version 2.14svn-r5318)

/* This code comes from The Official Asymptote Gallery */
    
size(0,100);
path unitcircle=E..N..W..S..cycle;
path g=scale(2)*unitcircle;
label("$a \le r \le b$");
radialshade(unitcircle^^g,yellow+evenodd,(0,0),1.0,yellow+brown,(0,0),2);

Mots-clefs : Basis, path, Shading

Comments (0)

Page 10 of 27
<
1
...
5
6
7
8
9
10
11
12
13
14
...
27
>

Administrateur-Développeur GNU/Linux-WEB