Développeur PHP/Zend/Typo3 - Administrateur Linux

Asymptote Generalities – fig1880

Category: Asymptote,Examples 2D,Generalities — Ph. Ivaldi @ 5 h 39 min

You may view all the posts of the category "Generalities"



(Compiled with Asymptote version 2.14svn-r5318)

    
size(8cm,0);

pair[] self_intersection(path p, int n=100)
{
  pair[] rpair=new pair[];
  path tpath;
  real [] tpoint;
  real l=length(p);
  int i=1;
  for (real t1=0; t1<l ; t1+=l/n)
    {
      for (real t2=t1+2*l/n; t2<l; t2+=l/n)
        {
          tpoint=intersect(subpath(p,t1,t1+l/n),
                           subpath(p,t2,t2+l/n));
          if (tpoint.length == 2)
            {
              rpair[i]=point(subpath(p,t1,t1+l/n),tpoint[0]);
              ++i;
            }
        }
    }
  return rpair;
}

void dott(pair[] pt, pen p)
{
  for (int i=1 ; i<pt.length; ++i)
    {
      dot(pt[i], p);
    }
}

srand(rand());
path p = randompath(15);

pair[] inter=self_intersection(p);
dott(inter, .8red);
draw(p);

Mots-clefs : Intersection, path, Random

Comments (0)

Asymptote Generalities – fig1870

Category: Asymptote,Examples 2D,Generalities — Ph. Ivaldi @ 4 h 39 min

You may view all the posts of the category "Generalities"



(Compiled with Asymptote version 2.14svn-r5318)

    
size(15cm,0);

srand(rand());
path p1 = randompath(9);
path p2 = randompath(8);
real Minx=min(min(p1).x,min(p2).x);
real Maxx=max(max(p1).x,max(p2).x);
real Miny=min(min(p1).y,min(p2).y);

pair[] inter=intersectionpoints(p1,p2);
int nb=inter.length;
for (int i=0 ; i<nb; ++i)
  {
    dot(inter[i]);
    label("$" + (string) i +"$", inter[i],N);
  }

draw(p1,.8red);
draw(p2,.8green);
label("I found " + (string) nb + " points of intersection.",((Maxx+Minx)/2,Miny),2S);

Mots-clefs : Basis, Intersection, path, Random

Comments (0)

Asymptote Generalities – fig1860

Category: Asymptote,Examples 2D,Generalities — Ph. Ivaldi @ 3 h 39 min

You may view all the posts of the category "Generalities"



(Compiled with Asymptote version 2.14svn-r5318)

    
// Venn diagram // Diagramme de Venn
// Edwards' construction // Construction d'Edwards
import roundedpath;
size(10cm,0);
path [] EdVenn(int n)
{
  path [] opath;
  if (n>=1)
    opath.push(shift(-1.4,-.9)*roundedpath(xscale(2.8)*yscale(.9)*unitsquare,.1));
  if (n>=2)
    opath.push(shift(0,-.9)*roundedpath(xscale(1.4)*yscale(1.8)*unitsquare,.1));
  if (n>=3)
    opath.push(scale(.5)*unitcircle);
  for (int i=1; i<=n-3; ++i)
    {
      pair pcle=point(opath[2],1/(2^i)),
        ccle=intersectionpoint(pcle--(pcle-dir(opath[2],1/(2^i))), (0,0)--(1,0));
      path cle=shift(ccle)*scale(abs(pcle-ccle))*unitcircle;
      real[] p1=intersect(cle, opath[2]);
      path ocle=subpath(cle,-p1[0],p1[0]);
      guide tpath;
      real step=360/(2^i), a=0;
      for (int j=0; j<2^i; ++j)
        {
          tpath=tpath..rotate(a)*ocle;
          a+=step;
        }
      opath.push(tpath..cycle);      
    }
    return opath;
}

draw(EdVenn(6));

Mots-clefs : array, Function (creating), path, Venn diagram

Comments (0)

Asymptote Generalities – fig1850

Category: Asymptote,Examples 2D,Generalities — Ph. Ivaldi @ 2 h 39 min

You may view all the posts of the category "Generalities"



(Compiled with Asymptote version 2.14svn-r5318)

    
//Translate from http://zoonek.free.fr/LaTeX/Metapost/metapost.html
size(0,0);

defaultpen(linewidth(1bp));
real u=3cm;
pair A, B, C, D, E;
path p, q, r;

A = u*up;
p = interp(A, rotate(72)*A, -.2) -- interp(A, rotate(72)*A,1.2);
for(int i=0; i<=5; ++i)
  draw(rotate(72i)*p);

B = midpoint(A--rotate(72)*A );
C = .8*B;

p = B --- C .. (rotate(2*72)*C){right};
// On allonge le chemin p
p = (point(p,0) - 4mm*dir(p,0.001))
  --
  point(p,0)
  & p &
  point(p,2)
  --
  (point(p,2) + 4mm*dir(p,2));

E = intersectionpoint(p, rotate(72)*p);
q = firstcut(p,shift(E)*scale(2mm)*unitcircle).before;
r = lastcut(p,shift(E)*scale(2mm)*unitcircle).after;

for(int i=0; i<=4; ++i)
  {
    draw(rotate(72i)*q);
    draw( rotate(72i)*r);
    draw(rotate(72i)*A,linewidth(4bp));
    draw(rotate(72i)*B,linewidth(4bp));
    draw(rotate(72i)*C,linewidth(4bp));
  }

Mots-clefs : Intersection, path

Comments (0)

Asymptote Generalities – fig1840

Category: Asymptote,Examples 2D,Generalities — Ph. Ivaldi @ 1 h 39 min

You may view all the posts of the category "Generalities"



(Compiled with Asymptote version 2.14svn-r5318)

    
size(6cm,0);

defaultpen(2mm+linecap(0));

path p = (0,0){up} .. (2cm,0){up};
path q = (0,1cm){dir(-60)}..(1cm,-1cm)..{dir(60)}(2cm,1cm);

real[] ipq=intersect(p,q);
real[] iprq=intersect(p,reverse(q));

draw(subpath(p, 0, ipq[0]), .8red);
draw(subpath(p, ipq[0], iprq[0]), .5red);
draw(subpath(p, iprq[0], length(p)), .3red);

draw(subpath(reverse(q), 0, iprq[1]), .8green);
draw(subpath(reverse(q), iprq[1], length(q)-ipq[1]), .5green);
draw(subpath(reverse(q), length(q)-ipq[1], length(q)), .3green);

Mots-clefs : Basis, Intersection, path

Comments (0)

Asymptote Generalities – fig1830

Category: Asymptote,Examples 2D,Generalities — Ph. Ivaldi @ 12 h 39 min

You may view all the posts of the category "Generalities"



(Compiled with Asymptote version 2.14svn-r5318)

    
size(6cm,0);
defaultpen(2mm+linecap(0));

path p = (0,0){up} .. (2cm,0){up};
path q = (0,1cm){dir(-60)}..(1cm,-1cm)..{dir(60)}(2cm,1cm);


draw(firstcut(p,q).before, .8red);
draw(firstcut(p,q).after, .8blue);

draw(lastcut(q,p).before, .8green);
draw(lastcut(q,p).after, .8yellow);

Mots-clefs : Basis, Intersection, path

Comments (0)

Asymptote Generalities – fig1810

Category: Asymptote,Examples 2D,Generalities — Ph. Ivaldi @ 10 h 39 min

You may view all the posts of the category "Generalities"



(Compiled with Asymptote version 2.14svn-r5318)

    
size(6cm,0);
import math;

pair project(pair pt, pair A, pair B)
  {
    return extension(pt,pt-dir(90+degrees(A-B,false)),A,B);
  }


pair ecenter(pair A, pair B, pair C)
  {
    return extension(A, A+rotate(90)*dir(A--B,A--C), B, B+rotate(90)*dir(B--A,B--C));
  }

path ecircle(pair A, pair B, pair C)
  {
    return shift(ecenter(A,B,C))*scale(abs(ecenter(A,B,C)-project(ecenter(A,B,C),B,C)))*unitcircle;
  }

pair A=(0,0), B=(3,0), C=(3,4);
path tr=A--B--C--cycle;

draw(ecircle(A,B,C));
draw(ecircle(B,C,A));

pen p=linewidth(1pt);
drawline(A,B, p);
drawline(A,C, p);
drawline(B,C, p);

Mots-clefs : Basis, Circle, Function (creating), Geometry, Intersection, line

Comments (0)

Asymptote Generalities – fig1800

Category: Asymptote,Examples 2D,Generalities — Ph. Ivaldi @ 9 h 39 min

You may view all the posts of the category "Generalities"



(Compiled with Asymptote version 2.14svn-r5318)

    
size(6cm,0);

import math;

pair A=(0,0), B=(1,.5), C=(.25,1);

pair project(pair pt, pair A, pair B)
  {
    return extension(pt,pt-dir(90+degrees(A-B,false)),A,B);
  }

pair icenter(pair A, pair B, pair C)
  {
    return extension(A, A+dir(A--B,A--C), B, B+dir(B--A,B--C));
  }

draw(A--B--C--cycle);

pair ins=icenter(A,B,C);
pair iAB=project(ins,A,B);
pair iAC=project(ins,A,C);
pair iBC=project(ins,B,C);

dot(ins, red);
dot(iAB^^iAC^^iBC);
drawline(A, ins, dotted);
drawline(B, ins, dotted);
drawline(C, ins, dotted);
draw(shift(ins)*scale(abs(ins-iAB))*unitcircle);

Mots-clefs : Basis, Circle, Function (creating), Geometry, Intersection

Comments (0)

Asymptote Generalities – fig1790

Category: Asymptote,Examples 2D,Generalities — Ph. Ivaldi @ 8 h 39 min

You may view all the posts of the category "Generalities"



(Compiled with Asymptote version 2.14svn-r5318)

    
size(6cm,0);

import math;

pair A=(0,0), B=(1,.5), C=(.25,1);

pair ccenter(pair A, pair B, pair C)
  {
    pair mAB=midpoint(A--B);
    pair mAC=midpoint(A--C);
    return extension(mAB, rotate(90,mAB)*A, mAC, rotate(90,mAC)*A);
  }

draw(A--B--C--cycle);

pair circ=ccenter(A,B,C);
pair mAB=midpoint(A--B);
pair mAC=midpoint(A--C);
pair mBC=midpoint(B--C);

dot(circ, red);
dot(mAB^^mAC^^mBC);
drawline(mAB, circ, dotted);
drawline(mAC, circ, dotted);
drawline(mBC, circ, dotted);
draw(shift(circ)*scale(abs(circ-A))*unitcircle);

Mots-clefs : Basis, Circle, Function (creating), Geometry, Intersection

Comments (0)

Asymptote Generalities – fig1780

Category: Asymptote,Examples 2D,Generalities — Ph. Ivaldi @ 7 h 39 min

You may view all the posts of the category "Generalities"



(Compiled with Asymptote version 2.14svn-r5318)

    
size(6cm,0);

import math;

pair A=(0,0), B=(1,.5), C=(.25,1);

pair project(pair pt, pair A, pair B)
  {
    return extension(pt,pt-dir(90+degrees(A-B,false)),A,B);
  }

pair ocenter(pair A, pair B, pair C)
  {
    return extension(A, project(A,B,C), B, project(B,A,C));
  }

draw(A--B--C--cycle);

pair orth=ocenter(A,B,C);
pair Ap=project(A,B,C);
pair Bp=project(B,A,C);
pair Cp=project(C,A,B);

dot(orth, red);
dot(Ap^^Bp^^Cp);
drawline(A, orth, dotted);
drawline(B, orth, dotted);
drawline(C, orth, dotted);

Mots-clefs : Basis, Function (creating), Geometry, Intersection

Comments (0)

Page 2 of 20
<
1
2
3
4
5
6
7
8
9
10
...
20
>

PIPRIME.FR

Administrateur-Développeur GNU/Linux-WEB

Asymptote Generalities – fig1880

Asymptote Generalities – fig1870

Asymptote Generalities – fig1860

Asymptote Generalities – fig1850

Asymptote Generalities – fig1840

Asymptote Generalities – fig1830

Asymptote Generalities – fig1810

Asymptote Generalities – fig1800

Asymptote Generalities – fig1790

Asymptote Generalities – fig1780