Développeur PHP/Zend/Typo3 - Administrateur Linux

Asymptote using geometry.asy – fig0370

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 6 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(10cm);

// currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,.75));
// show(currentcoordsys);

point A=(-1,-1);
point B=(2,1);
dot("$A$",A,S,red);
dot("$B$",B,N,red);

line l=line(A,B);
draw(l);

point F=(2,-1.5);
dot("$F$",F,N);

parabola p=parabola(F,0.2,110);
draw(p);

/* View the definition of point[] intersectionpoints(line,parabola) */
point[] inter=intersectionpoints(l,p);
dot("$M$", inter[0], 2N+E, red);
dot("$N$", inter[1], S+2E, red);

Mots-clefs : Geometry, Intersection, line, parabola

Comments (0)

Asymptote using geometry.asy – fig0360

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 5 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(8cm,0);

currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,.75));
show(currentcoordsys);

point A=(-1,0);
point B=(0.5,-3sin(2));
dot("$A$",A,S,red);
dot("$B$",B,N,red);

line l=line(A,B);
ellipse el=ellipse((0,-sqrt(2)/2),3,2,90);
draw(l);
draw(el,Arrow);

/* View the definition of point[] intersectionpoints(line,ellipse) */
point[] inter=intersectionpoints(l,el);
dot("$M$", inter[0], 4N+2W, red);
dot("$N$", inter[1], 2S+0.5E, red);

Mots-clefs : ellipse, Geometry, Intersection, line

Comments (0)

Asymptote using geometry.asy – fig0350

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 4 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(8cm,0);

currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,.75));
show(currentcoordsys, xpen=invisible);

point A=(-1,0);
point B=(0.5,-3sin(2));
dot("$A$",A,S,red);
dot("$B$",B,N,red);

line l=line(A,B);
circle c=circle((point)(0,-sqrt(2)/2),exp(1));
draw(l);
draw(c);

/* View the definition of point[] intersectionpoints(line,circle) */
point[] inter=intersectionpoints(l,c);
dot("$M$", inter[0], 2S, red);
dot("$N$", inter[1], 2N+0.5W, red);

Mots-clefs : Circle, Geometry, Intersection, line

Comments (0)

Asymptote using geometry.asy – fig0340

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 3 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(10cm,0);

// currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,.75));
// show(currentcoordsys);

point F1=(1,0);
point F2=(4,1);
dot("$F_1$",F1,W);
dot("$F_2$",F2);

// Enlarge the bounding box of the current picture
draw(box((0,-2), (5,4)), invisible);

/* View the definition of hyperbola hyperbola(point,point,real,bool) */
hyperbola h=hyperbola(F1, F2, 0.9);
draw(h, linewidth(3mm));
draw(h.A1, grey);
draw(h.A2, grey);
draw(h.D1);
draw(h.D2);

/* View the definition of hyperbola hyperbola(point,real,real,real) */
draw(hyperbola(h.C, h.a, h.b, h.angle), 2mm+green);

/* View the definition of hyperbola hyperbola(bqe) */
draw(hyperbola(equation(h)), 1mm+red);

/* View the definition of hyperbola conj(hyperbola) */
hyperbola ch=conj(h);
draw(ch, blue);
draw(ch.A1, 0.5blue);
draw(ch.A2, 0.5blue);
draw(ch.D1);
draw(ch.D2);
dot("${V'}_1$", ch.V1, NE);
dot("${V'}_2$", ch.V2, SW);
dot("${F'}_1$", ch.F1, S);
dot("${F'}_2$", ch.F2, N);

dot("$V_1$", h.V1, 2E, linewidth(2mm));
dot("$V_2$", h.V2, 2W, linewidth(2mm));

Mots-clefs : clip, deferred drawing, draw (2D), Geometry, hyperbola, line

Comments (0)

Asymptote using geometry.asy – fig0330

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 2 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(10cm);

point F=(2,-1.5);
dot("$F$",F,N,red);

// Enlarge the bounding box of the current picture.
draw(box((-1,-1),(3,1.5)),dashed);//,invisible);

parabola p=parabola(F,0.2,90);

// Define the bounding box to draw the parabola.
// Try finalbounds(); to determine the final bounding box.
p.bmin=(-0.75,-0.4);
p.bmax=(2.75,0.75);

draw(box(p.bmin,p.bmax),red);

draw(p,dashed);/* Defered drawing to adjust the path to the final
                  bounding box.*/

draw((path)p,red); /* The path of 'p' is restricted to the box whose
                  the corners are p.bmin, p.bmax.*/

Mots-clefs : clip, deferred drawing, draw (2D), Geometry, parabola

Comments (0)

Asymptote using geometry.asy – fig0320

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 1 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(10cm,0);

currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,.75));
show(currentcoordsys);

point F=(0.25,0.5);

dot("$F$",F,SW,red);

// Enlarge the bounding box of the current picture
draw(box(locate((-1.5,0)),locate((1,1))), invisible);

line l=rotateO(10)*line((0,-0.4),(1,-0.4));
draw(l);

/* View the definition of parabola parabola(point,line) */
parabola p=parabola(F,l);
draw(p,linewidth(3mm));

/* View the definition of parabola parabola(point,point) */
draw(parabola(p.F,p.V),2mm+red);

/* View the definition of parabola parabola(point,real,real) */
draw(parabola(p.F,p.a,p.angle),1mm+green);

Mots-clefs : coords system, Geometry, parabola

Comments (0)

Asymptote using geometry.asy – fig0310

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 12 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(10cm,0);

currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,.75));
show(currentcoordsys);

point A=(1,1);
dot("$A$",A,S,red);

real a=3, b=2;
ellipse el=ellipse(A,a,b,0);
draw(el,Arrow);

/* View the definition of ellipse *(transform,ellipse) */
draw(scale(0.5)*el,red,Arrow);

draw(scale(0.5,A)*el,2mm+0.8*blue);

/* View the definition of ellipse /(ellipse,real) */
draw(el/2,0.75mm+green,Arrow(4mm));

// Note that the point 'point(el,0)' is always at the same place relatively to 'el'.
draw(rotateO(135)*el/2,0.8*yellow,Arrow);

Mots-clefs : Circle, coords system, ellipse, Geometry, Transform

Comments (0)

Asymptote using geometry.asy – fig0300

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 11 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(8cm,0);

currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,.75));
show(currentcoordsys);

point A=(1,1);
dot("$A$",A,S,red);

real R=2;
circle C=circle(A,R);
draw(C,Arrow);

/* View the definition of ellipse *(transform,circle) */
draw(scale(0.5)*C,red,Arrow);

draw(scale(0.5,A)*C,2mm+0.8*blue);

/* View the definition of circle /(explicit circle,real) */
draw(C/2,0.75mm+green,Arrow(4mm));

// Note that the point 'point(C,0)' is always at the same place relatively to 'C'.
draw(rotateO(180)*C/2,0.8*yellow,Arrow);

Mots-clefs : Circle, coords system, ellipse, Geometry, Transform

Comments (0)

Asymptote using geometry.asy – fig0290

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 10 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(8cm,0);

currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,.75));
show(currentcoordsys);

point A=(1,1);
dot("$A$",A,S,red);

real R=2;
circle C=circle(A,R);
draw(C,Arrow);

/* View the definition of ellipse *(transform,circle) */
ellipse el=xscale(2)*C;
draw(el,blue,Arrow);

// /* View the definition of transform xscale(real,point) */
ellipse el=xscale(2,A)*C;
draw(el,red,Arrow);

Mots-clefs : Circle, coords system, ellipse, Geometry, Transform

Comments (0)

Asymptote using geometry.asy – fig0280

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 9 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(10cm);

// currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,0.75));
// show(currentcoordsys);

point A=(-1,0), B=(2,0), C=(0,2);

draw(line(A,B), linewidth(bp));
draw(line(A,C), linewidth(bp));
draw(line(B,C), linewidth(bp));

/* View the definition of circle circle(point,point,point) */
circle cc=circle(A,B,C);
draw(cc, blue);
dot(cc.C, blue);

/* View the definition of circle incircle(point,point,point) */
circle ic=incircle(A,B,C);
draw(ic, red);
dot(ic.C, red);


/* View the definition of circle excircle(point,point,point) */
circle ec=excircle(A,B,C);
/* View the definition of void clipdraw(picture,Label,path,align,pen,arrowbar,arrowbar,real,real,Label,marker) */
clipdraw(ec, green);
dot(ec.C, green);

ec=excircle(A,C,B);
clipdraw(ec, green);
dot(ec.C, green);

ec=excircle(C,B,A);
clipdraw(ec, green);
dot(ec.C, green);

dot("G",centroid(A,B,C),NE);

// Enlarge the bounding box of the current picture
// draw(box((-2.5,-3), (3.5,3.5)));

Mots-clefs : Circle, clip, Geometry, point

Comments (0)

Page 9 of 12
<
1
...
3
4
5
6
7
8
9
10
11
12
>

PIPRIME.FR

Administrateur-Développeur GNU/Linux-WEB

Asymptote using geometry.asy – fig0370

Asymptote using geometry.asy – fig0360

Asymptote using geometry.asy – fig0350

Asymptote using geometry.asy – fig0340

Asymptote using geometry.asy – fig0330

Asymptote using geometry.asy – fig0320

Asymptote using geometry.asy – fig0310

Asymptote using geometry.asy – fig0300

Asymptote using geometry.asy – fig0290

Asymptote using geometry.asy – fig0280