Développeur PHP/Zend/Typo3 - Administrateur Linux

Asymptote using geometry.asy – fig1140

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 11 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(8cm,0);

// currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,0.75));
// show(currentcoordsys);

triangle t=rotate(-20)*triangle((-1,0), (2,0), (0,2));
drawline(t, linewidth(bp));
label(t, alignAngle=90, alignFactor=2);

/* View the definition of point incenter(triangle) */
point incenter=incenter(t);

line ba=bisector(t.VA);
draw(ba, blue);
markangle((line) t.AB, (line) t.AC,StickIntervalMarker(i=2,n=1));

line bb=bisector(t.VB);
draw(bb, blue);
markangle((line) t.BC, (line) t.BA, radius=2cm, StickIntervalMarker(i=2,n=2));

line bc=bisector(t.VC);
draw(bc, blue);
markangle((line) t.CA, (line) t.CB, radius=1.5cm, StickIntervalMarker(i=2,n=3));

Mots-clefs : Geometry, line, Markers, point, triangle

Comments (0)

Asymptote using geometry.asy – fig1130

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 10 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(8cm,0);

// currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,0.75));
// show(currentcoordsys);

triangle t=rotate(-20)*triangle((-1,0), (2,0), (0,2));
drawline(t, linewidth(bp));
label(t,alignFactor=4);

line bab=bisector(t.AB);
draw(bab, blue);
perpendicularmark(t.AB,bab,quarter=4);

line bac=bisector(t.AC);
draw(bac, blue);
perpendicularmark(t.AC,bac,quarter=4);

line bbc=bisector(t.BC);
draw(bbc, blue);
perpendicularmark(t.BC,bbc,quarter=4);

Mots-clefs : Geometry, line, Markers, perpendicular, Transform, triangle

Comments (0)

Asymptote using geometry.asy – fig1120

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 9 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(10cm,0);

// currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,0.75));
// show(currentcoordsys);

triangle t=triangle((-1,0), (2,0), (0,2));

drawline(t, linewidth(bp));
label(t,alignFactor=2, alignAngle=90);

/* View the definition of triangle symmedial(triangle) */
triangle st=symmedial(t);
draw(st, bp+0.8green);
label("$A'$", "$B'$", "$C'$", st, alignAngle=45, 0.8green);

/* View the definition of line median(vertex) */
line mA=median(t.VA);
draw(mA, blue);
dot("$M_A$",midpoint(t.BC), 1.5E, blue);
draw(segment(t.BC), bp+blue, StickIntervalMarker(2,2,blue));

/* View the definition of line bisector(vertex,real) */
line bA=bisector(t.VA);
draw(bA, grey);
/* View the definition of point bisectorpoint(side) */
dot("$B_A$", bisectorpoint(t.BC));

/* View the definition of line symmedian(vertex) */
line sA=symmedian(t.VA);
draw(sA, 0.8*green);

draw(symmedian(t.VB), 0.8*green);
draw(symmedian(t.VC), 0.8*green);

/* View the definition of point symmedian(triangle) */
point sP=symmedian(t);
dot(sP);

markangle(sA, (line) t.AC, radius=2cm, StickIntervalMarker(1,1));
markangle((line) t.AB, mA, radius=2cm, StickIntervalMarker(1,1));
markangle(mA, sA, radius=10cm, StickIntervalMarker(2,2));

Mots-clefs : Geometry, Label, line, Markers, point, triangle

Comments (0)

Asymptote using geometry.asy – fig1110

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 8 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(10cm,0);

// currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,0.75));
// show(currentcoordsys);

triangle t=triangle((-1,0), (2,0), (0,2));

/* View the definition of void drawline(picture,triangle,pen) */
drawline(t, linewidth(bp));
/* View the definition of void label(picture,Label,Label,Label,triangle,real,real,pen,filltype) */
label(t,alignFactor=4);

/* View the definition of circle circle(triangle) */
circle cc=circle(t);
draw(cc, 0.8blue);
dot(cc.C, blue);
/* View the definition of triangle tangential(triangle) */
triangle tgt=tangential(t);
draw(tgt, bp+0.8blue);
label("$A_1$", "$B_1$", "$C_1$", tgt, blue);

/* View the definition of circle incircle(triangle) */
circle ic=incircle(t);
draw(ic, 0.8red);
dot(ic.C, red);
triangle intouch=intouch(t);
draw(intouch, bp+0.8red);
label("$A_2$", "$B_2$", "$C_2$", intouch, red);

/* View the definition of circle excircle(side,triangle) */
circle ec=excircle(t.AB);
clipdraw(ec, 0.8green);
dot(ec.C, green);

ec=excircle(t.AC);
clipdraw(ec, 0.8green);
dot(ec.C, green);

ec=excircle(t.BC);
clipdraw(ec, 0.8green);
dot(ec.C, green);

/* View the definition of triangle extouch(triangle) */
triangle ext=extouch(t);
draw(ext, bp+0.8green);
label("$A_3$", "$B_3$", "$C_3$", ext, green);

/* View the definition of point extouch(side) */
dot(extouch(t.AB), 0.8*green);
dot(extouch(t.BC), 0.8*green);
dot(extouch(t.CA), 0.8*green);

/* View the definition of point intouch(side) */
dot(intouch(t.AB), 0.8*red);
dot(intouch(t.BC), 0.8*red);
dot(intouch(t.CA), 0.8*red);

// Enlarge the bounding box of the current picture
draw(box((-2.5,-3), (3.5,3.5)), invisible);

Mots-clefs : Circle, Geometry, Label, line, point, tangent, triangle

Comments (0)

Asymptote using geometry.asy – fig1100

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 7 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(10cm,0);

// currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,0.75));
// show(currentcoordsys);

triangle t=triangle((-1,0), (2,0), (0,2));

drawline(t, linewidth(bp));
/* View the definition of void label(picture,Label,Label,Label,triangle,real,real,pen,filltype) */
label(t, alignFactor=4);

/* View the definition of triangle anticomplementary(triangle) */
triangle at=anticomplementary(t);
draw(at, bp+0.8green);
label("$A'$", "$B'$", "$C'$", at, blue);

draw(segment(at.AB), bp+0.8green, StickIntervalMarker(2,1));
draw(segment(at.BC), bp+0.8green, StickIntervalMarker(2,2));
draw(segment(at.CA), bp+0.8green, CrossIntervalMarker(2,3));

Mots-clefs : Geometry, Label, Markers, segment, triangle

Comments (0)

Asymptote using geometry.asy – fig1090

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 6 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;

size(10cm);

// currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,.75));
// show(currentcoordsys);

/* View the definition of triangle triangleAbc(real,real,real,real,point) */
triangle t=triangleAbc(60,3,5,angle=90);
show(Lb="3", Lc="5",t);
markangle("$60^\circ$",t.B,t.A,t.C);

Mots-clefs : Geometry, Markers, triangle

Comments (0)

Asymptote using geometry.asy – fig1080

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 5 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;

size(10cm);

// currentcoordsys=cartesiansystem((2,1),i=(1,0.5),j=(-0.25,.75));
// show(currentcoordsys);

/* View the definition of triangle triangleabc(real,real,real,real,point) */
triangle t=triangleabc(3,4,5);
/* View the definition of void show(picture,Label,Label,Label,Label,Label,Label,triangle,pen,filltype) */
show(La="3", Lb="4", Lc="5",t);

Mots-clefs : Geometry, triangle

Comments (0)

Asymptote using geometry.asy – fig1070

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 4 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(8cm,0);

// currentcoordsys=cartesiansystem((1,2),i=(1,0.5),j=(-0.5,.75));
show(currentcoordsys, xpen=invisible);

/* View the definition of struct mass */
mass A=mass((1,0),3);/* View the definition of mass mass(point,real) */

mass B=mass((0,1),sqrt(3));
point C=(0.25,0);

/* View the definition of void dot(picture,Label,mass,align,string,pen) */
dot("$\left(B;\sqrt{3}\right)$",B,N,format="");

dot("C",C,S);
dot("A",A,S);
draw(A--B--C--cycle);

/* View the definition of mass masscenter(... mass[]) */
dot("G",masscenter(A,B,mass(C)),S);

Mots-clefs : Geometry, mass, point, Point/Dot

Comments (0)

Asymptote using geometry.asy – fig1060

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 3 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(10cm,0);

// currentcoordsys=cartesiansystem((1,2),i=(1,0.5),j=(-0.5,.75));
show(currentcoordsys, xpen=invisible);

point A=(1,2);
point B=A+(2,0);
dot("$A$",A,0.25S+2W,red);
dot("$B$",B,0.25S+2E,red);

for (int i=0; i < 2; ++i) {
  real a=(i == 0) ? 60 : -100;
  /* View the definition of point arcsubtendedcenter(point,point,real) */
  dot(arcsubtendedcenter(A,B,a),2mm+blue);
  
  point arccenter=arcsubtendedcenter(A,B,a/2);
  dot(arccenter,2mm+red);

  /* View the definition of arc arcsubtended(point,point,real) */
  arc arcsubtended=arcsubtended(A,B,a);
  draw(arcsubtended,blue);

  arc arc=arcsubtended(A,B,a/2);
  draw(arc,red);
  
  point M=relpoint(arcsubtended,0.75);
  dot(format("%0g",degrees(B-M)-degrees(A-M)),
      M,(-1)^(i+1)*I*dir(arcsubtended,reltime(arcsubtended,0.6)));
  draw(A--M--B,blue);

  label(format("%0g",degrees(B-arccenter)-degrees(A-arccenter)),
      arccenter,(-1)^(i+1)*S);
  draw(A--arccenter--B,red);
 }

Mots-clefs : arc, Geometry, point

Comments (0)

Asymptote using geometry.asy – fig1050

Category: Asymptote,Examples 2D,geometry.asy — Ph. Ivaldi @ 2 h 02 min

You may view all the posts of the category "geometry.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import geometry;
size(8cm,0);

// currentcoordsys=cartesiansystem((1,2),i=(1,0.5),j=(-0.5,.75));
// show(currentcoordsys, xpen=invisible);

point A=(0.25,0.25);
point B=A+(1,0.25);
dot("$A$",A,S,red);
dot("$B$",B,N,red);

segment s=segment(A,B);
line bis=bisector(s);

draw(s,StickIntervalMarker(2,2));
draw(bis);

/* View the definition of path compassmark(pair,pair,real,real) */
draw(compassmark(A, point(bis,0.75), position=0.25,angle=25), grey);
draw(compassmark(B, point(bis,0.75), position=0.75,angle=25), grey);

/* View the definition of point point(line,real) */
draw(compassmark(A, point(bis,0.25), position=0.5,angle=15), grey);
draw(compassmark(B, point(bis,0.25), position=0.5,angle=15), grey);

Mots-clefs : Geometry, Intersection, line, Markers, point, segment

Comments (0)

Page 10 of 40
<
1
...
5
6
7
8
9
10
11
12
13
14
...
40
>

PIPRIME.FR

Administrateur-Développeur GNU/Linux-WEB

Asymptote using geometry.asy – fig1140

Asymptote using geometry.asy – fig1130

Asymptote using geometry.asy – fig1120

Asymptote using geometry.asy – fig1110

Asymptote using geometry.asy – fig1100

Asymptote using geometry.asy – fig1090

Asymptote using geometry.asy – fig1080

Asymptote using geometry.asy – fig1070

Asymptote using geometry.asy – fig1060

Asymptote using geometry.asy – fig1050