Asymptote using graph3.asy – fig0080

Category: Asymptote,Examples 3D,graph3.asy — Ph. Ivaldi @ 10 h 11 min

You may view all the posts of the category "graph3.asy"
Figure 0008
(Compiled with Asymptote version 2.14svn-r5318) 
    
// Adapted from the documentation of Asymptote.
import graph3;
import contour;
texpreamble("\usepackage{icomma}");

size3(12cm,12cm,8cm,IgnoreAspect);

real sinc(pair z) {
  real r=2pi*abs(z);
  return r != 0 ? sin(r)/r : 1;
}

limits((-2,-2,-0.2),(2,2,1.2));
currentprojection=orthographic(1,-2,0.5);

xaxis3(rotate(90,X)*"$x$",
       Bounds(Min,Min),
       OutTicks(rotate(90,X)*Label, endlabel=false));

yaxis3("$y$", Bounds(Max,Min), InTicks(Label));
zaxis3("$z$", Bounds(Min,Min), OutTicks());

draw(lift(sinc,contour(sinc,(-2,-2),(2,2),new real[] {0})), bp+0.8*red);
draw(surface(sinc,(-2,-2),(2,2),nx=100, Spline), lightgray);

draw(scale3(2*sqrt(2))*unitdisk, paleyellow+opacity(0.25), nolight);
draw(scale3(2*sqrt(2))*unitcircle3, 0.8*red);

Mots-clefs : , , , ,

Asymptote using graph3.asy – fig0070

Category: Asymptote,Examples 3D,graph3.asy — Ph. Ivaldi @ 9 h 11 min

You may view all the posts of the category "graph3.asy"
Figure 0007
(Compiled with Asymptote version 2.14svn-r5318) 
    
import graph3;

size(8cm,0);
currentprojection=orthographic(1,1,0.5);
limits((-2,-2,0),(0,2,2));

xaxis3(Label("$x$",align=Z),
       Bounds(Min,Min),
       OutTicks(endlabel=false,Step=1,step=0.5));

yaxis3("$y$", Bounds(),
       OutTicks(pTick=0.8*red, ptick=lightgrey));

zaxis3("$z$", Bounds(),
       OutTicks, p=red, arrow=Arrow3);

dot(Label("",align=Z), (-1,0,0), red);

Mots-clefs : , ,

Asymptote using graph3.asy – fig0060

Category: Asymptote,Examples 3D,graph3.asy — Ph. Ivaldi @ 8 h 11 min

You may view all the posts of the category "graph3.asy"
Figure 0006
(Compiled with Asymptote version 2.14svn-r5318) 
    
import graph3;
usepackage("icomma");

size(8cm,0);
currentprojection=orthographic(1.5,1,1);

limits((-2,-1,-.5), (0,1,1.5));

xaxis3("$x$",
       Bounds(Both,Value),
       OutTicks(endlabel=false));

yaxis3("$y$",
       Bounds(Both,Value),
       OutTicks(Step=.5,step=.25));

zaxis3("$z$", XYEquals(-2,0), InOutTicks(Label(align=Y-X)));

dot(Label("",align=Z), (-1,0,0), red);

Mots-clefs : ,

Asymptote using graph3.asy – fig0050

Category: Asymptote,Examples 3D,graph3.asy — Ph. Ivaldi @ 7 h 11 min

You may view all the posts of the category "graph3.asy"
Figure 0005
(Compiled with Asymptote version 2.14svn-r5318) 
    
import graph3;

size(6cm,0);
currentprojection=orthographic(1,1,1);

limits((-2,-2,0),(0,2,2));

xaxis3(Label("$x$",MidPoint), OutTicks());
yaxis3("$y$", InTicks());
zaxis3("$z$",XYEquals(-2,0), OutTicks());

Mots-clefs : ,

Asymptote using graph3.asy – fig0040

Category: Asymptote,Examples 3D,graph3.asy — Ph. Ivaldi @ 6 h 11 min

You may view all the posts of the category "graph3.asy"
Figure 0004
(Compiled with Asymptote version 2.14svn-r5318) 
    
import graph3;

size(8cm,0);
currentprojection=orthographic(1,1,1);

defaultpen(overwrite(SuppressQuiet));

limits((0,-2,0),(2,2,2));

xaxis3("$x$", InTicks(XY()*Label));
yaxis3("$y$", InTicks(XY()*Label));
zaxis3("$z$", OutTicks, p=red, arrow=Arrow3);

Mots-clefs : ,

Asymptote using graph3.asy – fig0030

Category: Asymptote,Examples 3D,graph3.asy — Ph. Ivaldi @ 5 h 11 min

You may view all the posts of the category "graph3.asy"
Figure 0003
(Compiled with Asymptote version 2.14svn-r5318) 
    
import graph3;

size(8cm,0,IgnoreAspect);
currentprojection=orthographic(1,1,1);

limits((0,-2,0), (2,2,2));

axes3("$x$","$y$","$z$",Arrow3);

Mots-clefs : ,

Asymptote using graph3.asy – fig0020

Category: Asymptote,Examples 3D,graph3.asy — Ph. Ivaldi @ 4 h 11 min

You may view all the posts of the category "graph3.asy"
Figure 0002
(Compiled with Asymptote version 2.14svn-r5318) 
    
import graph3;

size(8cm,0);
currentprojection=orthographic(1,1,1);

limits((0,-2,0),(2,2,2));

xaxis3("$x$", OutTicks());
yaxis3("$y$", OutTicks());
zaxis3("$z$", OutTicks());

Mots-clefs : ,

Asymptote using graph3.asy – fig0010

Category: Asymptote,Examples 3D,graph3.asy — Ph. Ivaldi @ 3 h 11 min

You may view all the posts of the category "graph3.asy"
Figure 0001

A Möbius strip of half-width latex2png equation with midcircle of radius latex2png equation and at height latex2png equation can be represented parametrically by:

latex2png equation

for latex2png equation in latex2png equation and latex2png equation in latex2png equation. In this parametrization, the Möbius strip is therefore a cubic surface with equation

latex2png equation

Source
(Compiled with Asymptote version 2.14svn-r5318) 
    
import graph3;
ngraph=200;
size(12cm,0);
currentprojection=orthographic(-4,-4,5);

real x(real t), y(real t), z(real t);

real R=2;
void xyzset(real s){
  x=new real(real t){return (R+s*cos(t/2))*cos(t);};
  y=new real(real t){return (R+s*cos(t/2))*sin(t);};
  z=new real(real t){return s*sin(t/2);};
}


int n=ngraph;
real w=1;
real s=-w, st=2w/n;
path3 p;
triple[][] ts;
for (int i=0; i <= n; ++i) {
  xyzset(s);
  p=graph(x,y,z,0,2pi);

  ts.push(new triple[] {});
  for (int j=0; j <= ngraph; ++j) {
    ts[i].push(point(p,j));
  }
  s += st;
}

pen[] pens={black, yellow, red, yellow, black};
draw(surface(ts, new bool[][]{}), lightgrey);
for (int i=0; i <= 4; ++i) {
  xyzset(-w+i*w/2);
  draw(graph(x,y,z,0,2pi), 2bp+pens[i]);
}

Mots-clefs : , ,

  • Page 2 of 2
  • <
  • 1
  • 2

haut

Copyright © 2009 Philippe Ivaldi (pseudo : pivaldi)

Valide xhtml

Codes under the termes of the GNU LGPL.
Pictures under the termes of the CC Attribution ShareAlike 3.0
Powered by WordPress and a modified Stardust theme
webmaster-rank.info
Développeur Typo3 | Développeur PHP Zend | Développeur C++ | Administrateur Linux