Asymptote using solids.asy – fig0030

Catégorie : Asymptote, Examples 3D, solids.asy — Ph. Ivaldi @ 4 h 56 min

You may view all the posts of the category "solids.asy"
Figure 0003
(Compiled with Asymptote version 1.87svn-r4652) 
    
// Author: John Bowman.
size(6cm,0);
import solids;
currentprojection=orthographic(0,10,5);
currentlight=adobe;

nslice=4*nslice;

revolution r=sphere(O,1);
draw(surface(r), lightgrey+opacity(0.75));

skeleton s;
r.transverse(s,reltime(r.g,0.6));
r.transverse(s,reltime(r.g,0.5));
draw(s.transverse.back,linetype("8 8",8));
draw(s.transverse.front);

r.longitudinal(s);
draw(s.longitudinal.front);
draw(s.longitudinal.back,linetype("8 8",8));

Mots-clefs : , , , , , ,

Asymptote using solids.asy – fig0020

Catégorie : Asymptote, Examples 3D, solids.asy — Ph. Ivaldi @ 3 h 56 min

You may view all the posts of the category "solids.asy"
Figure 0002
(Compiled with Asymptote version 1.87svn-r4652) 
    
import solids;
currentlight=light(paleyellow, viewport=false,
                   (5,-5,10),(0,0,-10));

size(6cm,0);
draw(sphere(1,n=4*nslice), linewidth(bp), m=10);
draw(surface(sphere(1,n=4*nslice)), orange);

Mots-clefs : , , , , ,

Asymptote using solids.asy – fig0010

Catégorie : Asymptote, Examples 3D, solids.asy — Ph. Ivaldi @ 2 h 56 min

You may view all the posts of the category "solids.asy"
Figure 0001
(Compiled with Asymptote version 1.87svn-r4652) 
    
import solids;
currentprojection=orthographic(1,2,2);
currentlight=adobe;

size(6cm,0);
material m=
  //       diffusepen, ambientpen, emissivepen,  specularpen
  material(  grey,       yellow,     black,        orange);

draw(surface(sphere(1)), m);

Mots-clefs : , , , , ,

Asymptote using three.asy – fig0110

Catégorie : Asymptote, Examples 3D, three.asy — Ph. Ivaldi @ 0 h 50 min

You may view all the posts of the category "three.asy"
Figure 0011
(Compiled with Asymptote version 1.87svn-r4652) 
    
import three;
size(10cm,0);
currentprojection=orthographic(1,1.5,1);

path3 xy=XY*unitsquare3, xz=ZX*unitsquare3, yz=YZ*unitsquare3;

draw(xy^^xz^^yz, grey);
path3 p3xy=path3(texpath("$\pi$")[0],XYplane);
p3xy=shift((0.5,0.5,0))*scale3(1/abs(min(p3xy)-max(p3xy)))*p3xy;

surface s=surface(p3xy,planar=true);
draw(s, surfacepen=blue, meshpen=orange+3pt);

transform3 Txz=planeproject(xz,(0,-1,1));
draw(Txz*s, red);

transform3 Tyz=planeproject(yz,(-1,0,1));
draw(Tyz*s, green);

path3 p3xz=Txz*p3xy;
path3 p3yz=Tyz*p3xy;

int lg=length(p3xy);
triple p;
for(int i=0;i<=lg;++i) {
  p=point(p3xy,i);
  draw(p--point(p3xz,i), yellow);
  draw(p--point(p3yz,i), orange);
}

Mots-clefs : , , , ,

Asymptote using three.asy – fig0100

Catégorie : Asymptote, Examples 3D, three.asy — Ph. Ivaldi @ 23 h 50 min

You may view all the posts of the category "three.asy"
Figure 0010
(Compiled with Asymptote version 1.87svn-r4652) 
    
size(12cm,0);
import bsp;

currentprojection=orthographic(1,1.5,1);

path3 xy=plane((1,0,0),(0,1,0),(0,0,0));
path3 xz=rotate(90,X)*xy;
path3 yz=rotate(-90,Y)*xy;

face[] f;
filldraw(f.push(xy),project(xy),grey);
filldraw(f.push(xz),project(xz),grey);
filldraw(f.push(yz),project(yz),grey);
add(f);

draw(Label("$x$",EndPoint), O--(1,0,0), Arrow3);
draw(Label("$y$",EndPoint), O--(0,1,0), Arrow3);
draw(Label("$z$",EndPoint), O--(0,0,1), Arrow3);
dot(O);

path[] ph=texpath("$\displaystyle\int_{-\infty}^{+\infty}e^{-\alpha x^2}\,dx=
\sqrt{\frac{\pi}{\alpha}}$");
ph =shift((0.5,0.5))*rotate(-45)*scale(1/abs(min(ph)-max(ph)))*ph;

filldraw(project(path3(ph,XYplane)),0.8*yellow);
filldraw(project(path3(ph,ZXplane)),0.8*yellow);
filldraw(project(path3(ph,YZplane)),0.8*yellow);

shipout(bbox((palegrey)));

Mots-clefs : , , , , ,

Asymptote using three.asy – fig0090

Catégorie : Asymptote, Examples 3D, three.asy — Ph. Ivaldi @ 22 h 50 min

You may view all the posts of the category "three.asy"
Figure 0009
(Compiled with Asymptote version 1.87svn-r4652) 
    
size(10cm,0);
import three;

currentprojection=obliqueX;

triple v1=(4,0,0),
       v2=(0,6,0),
       p0=(-2,-3,0);
path3 pl1=plane(v1,v2,p0);

path ph=transform(v1,v2,p0,currentprojection)*((0,-2){W}..(0,2){W}..cycle);
filldraw(project(pl1)^^ph,evenodd+lightgrey);

Mots-clefs : , , , , ,

Asymptote using three.asy – fig0080

Catégorie : Asymptote, Examples 3D, three.asy — Ph. Ivaldi @ 21 h 50 min

You may view all the posts of the category "three.asy"
Figure 0008
(Compiled with Asymptote version 1.87svn-r4652) 
    
import bsp;

typedef path3[] shape;

shape operator *(transform3 T, shape p){
  shape os;
  for(path3 g:p) os.push(T*g);
  return os;
}


path3 path(triple[] T){
  path3 P;
  for(triple i:T) P=P--i;
  return P;
}

void addshapes(face[] F, shape[] shp, pen drawpen=currentpen, pen fillpen=white)
{
  for(int i=0; i < shp.length; ++i)
    for(int j=0; j < shp[i].length; ++j) {
      path3 g=shp[i][j];
      picture pic=F.push(g);
      if(fillpen != nullpen) filldraw(pic,project(g),fillpen, drawpen);
      else draw(pic,project(g),drawpen);
      // filldraw(pic,g,currentlight.intensity(F[F.length-1].point)*fillpen, drawpen);
    }
}

shape cylinder(real R=1, real H=1, int n=18){
  shape Cyl;
  triple[] CTop;
  triple[] CBot;
  for(int i=0; i <= n; ++i)
    CBot.push((R*cos(2pi*i/n), R*sin(2pi*i/n),0));
  CTop = CBot+(0,0,H);
  for(int i=0; i < n; ++i)
    Cyl.push(CBot[i]--CBot[i+1]--CTop[i+1]--CTop[i]--cycle);

  path3 P=path(CBot)--cycle;
  Cyl.push(P);
  Cyl.push(shift(H*Z)*P);

  return Cyl;
}


size(10cm,0);

currentprojection=orthographic(1,1,1);

shape cyl1 = cylinder(R=1, H=2);

shape[] group={cyl1};

face[] hidden, visible;
addshapes(hidden, group, drawpen=linewidth(bp));
addshapes(visible, group, drawpen=dotted, fillpen=nullpen);
add(hidden);
add(visible);

shipout(format="pdf");

Mots-clefs : , , ,

Asymptote using three.asy – fig0070

Catégorie : Asymptote, Examples 3D, three.asy — Ph. Ivaldi @ 20 h 50 min

You may view all the posts of the category "three.asy"
Figure 0007
(Compiled with Asymptote version 1.87svn-r4652) 
    
// From the Asymptote forum
import bsp;

typedef path3[] shape;

shape operator *(transform3 T, shape p){
  shape os;
  for(path3 g:p) os.push(T*g);
  return os;
}


path3 path(triple[] T){
  path3 P;
  for(triple i:T) P=P--i;
  return P;
}

void addshapes(face[] F, shape[] shp, pen drawpen=currentpen, pen fillpen=white)
{
  for(int i=0; i < shp.length; ++i)
    for(int j=0; j < shp[i].length; ++j) {
      path3 g=shp[i][j];
      picture pic=F.push(g);
      filldraw(pic,project(g),fillpen, drawpen);
      // filldraw(pic,g,currentlight.intensity(F[F.length-1].point)*fillpen, drawpen);
    }
}

shape cylinder(real R=1, real H=1, int n=18){
  shape Cyl;
  triple[] CTop;
  triple[] CBot;
  for(int i=0; i <= n; ++i)
    CBot.push((R*cos(2pi*i/n), R*sin(2pi*i/n),0));
  CTop = CBot+(0,0,H);
  for(int i=0; i < n; ++i)
    Cyl.push(CBot[i]--CBot[i+1]--CTop[i+1]--CTop[i]--cycle);

  path3 P=path(CBot)--cycle;
  Cyl.push(P);
  Cyl.push(shift(H*Z)*P);

  return Cyl;
}

shape rightslab(real x=1, real y=1, real z=1){
  shape slab;
  slab[0] = (0,0,0)--(1,0,0)--(1,1,0)--(0,1,0)--cycle;
  slab[1] = (0,0,0)--(1,0,0)--(1,0,1)--(0,0,1)--cycle;
  slab[2] = (1,0,0)--(1,1,0)--(1,1,1)--(1,0,1)--cycle;
  slab[3] = (1,1,0)--(0,1,0)--(0,1,1)--(1,1,1)--cycle;
  slab[4] = (0,1,0)--(0,0,0)--(0,0,1)--(0,1,1)--cycle;
  slab[5] = (0,0,1)--(1,0,1)--(1,1,1)--(0,1,1)--cycle;
  return scale(x,y,z)*slab;
}

size(10cm,0);
triple cam=(1600,200,150);
//currentprojection=orthographic(1600,800,400);
currentprojection=perspective(cam); //Far away!
currentlight=rotate(-45,Z)*(cam+(0,0,1000));

real Blen = 180;
real Bwdt = 30;
real Bhgt = 3;
real Clen = 130;
real Cwdt = 50;
real Chgt = 50;
real cylr = 7.5;
real cylh = 37.0 ;

shape slab1 = shift(-Bwdt/2*Y-Bhgt/2*Z+Clen/2*X)*rightslab(Blen,Bwdt,Bhgt);
shape slab2 = shift(-Cwdt/2*Y-Chgt/2*Z-Clen/2*X)*rightslab(Clen,Cwdt,Chgt);
shape cyl1 = shift((Blen+Clen/2-2*cylr)*X-(cylh/2)*Z)*cylinder(R=cylr, H=cylh);

shape[] group1={slab1};
shape[] group2={slab2};
shape[] group3={cyl1};

face[] faces;
addshapes(faces, group1, drawpen=linewidth(0.25bp), fillpen=opacity(0.35)+red);
addshapes(faces, group2, drawpen=linewidth(0.25bp), fillpen=opacity(0.5)+lightblue);
addshapes(faces, group3, drawpen=linewidth(0.25bp), fillpen=opacity(0.5)+lightyellow);
add(faces);

shipout(format="pdf", bbox(3mm,white));

Mots-clefs : , ,

Asymptote using three.asy – fig0060

Catégorie : Asymptote, Examples 3D, three.asy — Ph. Ivaldi @ 19 h 50 min

You may view all the posts of the category "three.asy"
Figure 0006
(Compiled with Asymptote version 1.87svn-r4652) 
    
settings.render=0;
import three;
size(4cm,0);

currentprojection=perspective((45,45,30));
path3 YZ=plane((0,4,0),(0,0,4));

draw("$x$",project(O--X),Arrow);
draw("$y$",project(O--Y),Arrow);
draw("$z$",project(O--Z),Arrow);
draw(YZ);

label(scale(5)*project("A",Y,Z,(0,1,1)));

Mots-clefs : , ,

Asymptote using three.asy – fig0050

Catégorie : Asymptote, Examples 3D, three.asy — Ph. Ivaldi @ 18 h 50 min

You may view all the posts of the category "three.asy"
Figure 0005
(Compiled with Asymptote version 1.87svn-r4652) 
    
import three; import math;
size(8cm,0);
currentprojection=obliqueX;

real h=2;
triple A =(0,0,h), B=(h,0,0), C=(0,h,0), D=(0,0,0);
triple Ip=midpoint(A--C), J=midpoint(A--B);
triple K=shift((0,0,-0.25*h))*A;

triple M=interp(K,J,intersect(K,J,normal(new triple[]{B,C,D}),D));
triple Np=interp(K,Ip,intersect(K,Ip,normal(new triple[]{B,C,D}),D));

dot("$A$", A, align=Z);  dot("$B$", B, align=S);
dot("$C$", C, align=S);  dot("$D$", D, align=W);
dot("$I$", Ip, align=N); dot("$J$", J, align=W);
dot("$K$", K, align=NE); dot("$M$", M, align=SE);
dot("$N$", Np, align=S);

draw(A--B--C--cycle^^B--M^^C--Np^^J--M^^Ip--Np);
draw(A--D--C^^D--B^^J--K^^K--Ip, dashed);

Mots-clefs : , , , ,

haut

Copyright © 2009 Philippe Ivaldi (pseudo : pivaldi)

Valide xhtml

Codes under the termes of the GNU LGPL.
Pictures under the termes of the CC Attribution ShareAlike 3.0
Powered by WordPress and a modified Stardust theme
webmaster-rank.info
Développeur Typo3 | Développeur PHP | Développeur Shell | Développeur Python | Administrateur Linux