Développeur PHP/Zend/Typo3 - Administrateur Linux

Asymptote using tube.asy – fig0210

Category: Asymptote,Examples 3D,tube.asy — Ph. Ivaldi @ 3 h 11 min

You may view all the posts of the category "tube.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import tube;
import graph3;
import palette;

size(12cm,0);
currentprojection=perspective(1,1,1);

int e=1;
real x(real t) {return cos(t)+2*cos(2t);}
real y(real t) {return sin(t)-2*sin(2t);}
real z(real t) {return 2*e*sin(3t);}

path3 p=scale3(2)*graph(x,y,z,0,2pi,50,operator ..)&cycle;

pen[] pens=Rainbow(15);
pens.push(black);
for (int i=pens.length-2; i >= 0 ; --i)
  pens.push(pens[i]);

path sec=subpath(Circle(0,1.5,2*pens.length),0,pens.length);
coloredpath colorsec=coloredpath(sec, pens,colortype=coloredNodes);
draw(tube(p,colorsec));

Mots-clefs : Graph (3D), palette, Shading (3D), tube

Comments (0)

Asymptote using tube.asy – fig0200

Category: Asymptote,Examples 3D,tube.asy — Ph. Ivaldi @ 2 h 11 min

You may view all the posts of the category "tube.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
// Anneau de Borrommée
// Borromean rings

import tube;
import solids;

size(12cm,0);
currentprojection=perspective((0,0,1));

real a=5, b=2, sq3=sqrt(3);
for (int i=0; i <= 2; ++i) {
  real ai, bi;
  if(i == 0) {
    ai=a/2;
    bi=a*sq3/2;
  } else if(i == 1) {
    ai=-a/2;
    bi=a*sq3/2;
  } else {
    ai=0;
    bi=a*sq3;
  }
  real x(real t){return a*cos(t)+ai;}
  real y(real t){return a*sin(t)+bi;}
  real z(real t){return b*cos(3t);}

  path3 p=graph(x,y,z,0,2pi,100,operator ..)&cycle;


  real trig(real t){return 1-2*abs(t%1-0.5);}
  pen pens(real t) {
    real tt=trig(t+i/3);
    return interp(red,yellow,(tt));
  }

  draw(tube(p, coloredpath(polygon(4),pens)));
}

Mots-clefs : tube

Comments (0)

Asymptote using tube.asy – fig0190

Category: Asymptote,Examples 3D,tube.asy — Ph. Ivaldi @ 1 h 11 min

You may view all the posts of the category "tube.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import tube;
import solids;

size(12cm,0);
currentprojection=perspective((0,0,1));

int p=8, q=3;
real n=p/q, R=2, r=1;

real x(real t){return (R+r*cos(n*t))*cos(t);}
real y(real t){return (R+r*cos(n*t))*sin(t);}
real z(real t){return r*sin(n*t);}

path3 p=graph(x,y,z,0,6pi,200,operator ..)&cycle;

revolution torus=revolution(Circle(R*X,r,Y,10),Z);

transform T(real t){return scale(0.3+0.25*sin(t*20pi));}

pen[] bpen={0.5red,0.5blue};
bpen.cyclic=true;
pen pen(real t){return bpen[ceil(sin(t*20pi)-1e-3)];}

draw(tube(p,coloredpath(polygon(3),pen),T));
// draw(surface(torus),yellow);

Mots-clefs : tube

Comments (0)

Asymptote using tube.asy – fig0180

Category: Asymptote,Examples 3D,tube.asy — Ph. Ivaldi @ 12 h 11 min

You may view all the posts of the category "tube.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import tube;
import graph3;
size(12cm,0);

currentprojection=perspective(1,-1,0);


path3 p=scale3(20)*randompath3(20,false,operator--)--cycle;

path section=scale(1,0.25)*polygon(4);
draw(tube(roundedpath(p,0.05),section, corner=10), purple);

Mots-clefs : tube

Comments (0)

Asymptote using tube.asy – fig0170

Category: Asymptote,Examples 3D,tube.asy — Ph. Ivaldi @ 11 h 11 min

You may view all the posts of the category "tube.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import tube;
import graph3;
size(12cm,0);

currentprojection=perspective(1,-1,0);


path3 p=scale3(20)*randompath3(20,false,operator--)--cycle;

path section=scale(1,0.5)*unitcircle;
// path section=polygon(6);
// path section=scale(1,0.25)*polygon(4);
draw(tube(p,section), purple, bp+yellow);

Mots-clefs : tube

Comments (0)

Asymptote using tube.asy – fig0160

Category: Asymptote,Examples 3D,tube.asy — Ph. Ivaldi @ 10 h 11 min

You may view all the posts of the category "tube.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import tube;
import graph3;
size(12cm,0);

currentprojection=perspective(1,-1,0);

real x(real t)
{
return 41*cos(t)-18*sin(t)-83*cos(2t)-83*sin(2t)-11*cos(3t)+27*sin(3t);
}

real y(real t)
{
  return 36*cos(t)+27*sin(t)-113*cos(2t)+30*sin(2t)+11*cos(3t)-27*sin(3t);
}

real z(real t)
{
  return 45*sin(t)-30*cos(2t)+113*sin(2t)-11*cos(3t)+27*sin(3t);
}

path3 p=scale3(0.05)*graph(x,y,z,-pi,pi,200,operator --)&cycle;

path section=scale(2,0.5)*unitcircle;
// path section=scale(2,0.5)*polygon(4);
// path section=scale(2)*polygon(6);
draw(tube(p,section), purple);

Mots-clefs : tube

Comments (0)

Asymptote using tube.asy – fig0150

Category: Asymptote,Examples 3D,tube.asy — Ph. Ivaldi @ 9 h 11 min

You may view all the posts of the category "tube.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import tube;
import graph3;
size(12cm,0);
// currentprojection=perspective((2,1,6),-Z); real q=1;
currentprojection=perspective((-1,1,1)); real q=2;

real x(real t){return (1-cos(t))*cos(q*t);}
real y(real t){return (1-cos(t))*sin(q*t);}
real z(real t){return cos(3t);}

path3 p=graph(x,y,z,0,2pi,20,operator ..);
draw(tube(p,scale(0.4,0.1)*unitcircle), purple);

Mots-clefs : tube

Comments (0)

Asymptote using tube.asy – fig0140

Category: Asymptote,Examples 3D,tube.asy — Ph. Ivaldi @ 8 h 11 min

You may view all the posts of the category "tube.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import tube;
import graph;
size(12cm,0);
currentprojection=perspective(0,3,6);

real f(real t) {return cos(2*t);}
path g=polargraph(f,0,2pi,10,operator --)&cycle;
path3 p=path3(scale(20)*g);

draw(tube(p,2W--2E), red, bp+black);
draw(tube(p,unitcircle), orange, bp+black);

Mots-clefs : Graph, path, tube

Comments (0)

Asymptote using tube.asy – fig0130

Category: Asymptote,Examples 3D,tube.asy — Ph. Ivaldi @ 7 h 11 min

You may view all the posts of the category "tube.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import tube;
import graph;
size(12cm,0);
currentprojection=perspective(4,3,6);

real f(real t) {return cos(2*t);}
path g=polargraph(f,0,2pi,10,operator ..)&cycle;
path3 p=path3(scale(20)*g);

draw(tube(p,rotate(60)*polygon(3)), 0.8*red);
draw(tube(shift(Z)*p,scale(0.25)*unitcircle), orange);
draw(shift(1.25*Z)*p);

Mots-clefs : Graph, path, tube

Comments (0)

Asymptote using tube.asy – fig0120

Category: Asymptote,Examples 3D,tube.asy — Ph. Ivaldi @ 6 h 11 min

You may view all the posts of the category "tube.asy"



(Compiled with Asymptote version 2.14svn-r5318)

    
import tube;
import graph3;
size(12cm,0);
currentprojection=orthographic(1,0,6);

real x(real t) {return sin(t);}
real y(real t) {return 0.5*sin(2*t);}

path g=graph(x,y,0,2pi,50,operator ..);
path3 p=path3(scale(5)*g);

pen[] pens(real t){
  real tt=1-2*abs(t-0.5);
  return new pen[] {interp(red,blue,tt), interp(blue,red,tt)};
}

draw(tube(p,
          coloredpath(polygon(5),pens,colortype=coloredNodes)));
label("colortype=coloredNodes",8*X);

draw(tube(shift(10*Y)*p,
          coloredpath(polygon(5),pens,colortype=coloredSegments)));
label("colortype=coloredSegments",8*X+10Y);

Mots-clefs : Shading (3D), tube

Comments (0)

Page 1 of 3
1
2
3
>

PIPRIME.FR

Administrateur-Développeur GNU/Linux-WEB

Asymptote using tube.asy – fig0210

Asymptote using tube.asy – fig0200

Asymptote using tube.asy – fig0190

Asymptote using tube.asy – fig0180

Asymptote using tube.asy – fig0170

Asymptote using tube.asy – fig0160

Asymptote using tube.asy – fig0150

Asymptote using tube.asy – fig0140

Asymptote using tube.asy – fig0130

Asymptote using tube.asy – fig0120