Unofficial package graph_pi.asy – fig0010

Category: Asymptote,graph_pi.asy,Unofficial packagesPh. Ivaldi @ 5 h 50 min

Figure 0001
(Compiled with Asymptote version 2.14svn-r5318)
    
import graph_pi;

graphicrules(yunit=1.5cm, xmin=-3, xmax=3, ymin=-2, ymax=2);
grid();
cartesianaxis(arrow=None);
labeloij(UnFill);

Étiquettes : , ,


Unofficial package graph_pi.asy – fig0020

Category: Asymptote,graph_pi.asy,Unofficial packagesPh. Ivaldi @ 6 h 50 min

Figure 0002
(Compiled with Asymptote version 2.14svn-r5318)
    
import graph_pi;

graphicrules(yunit=1.5cm, xmin=-3, xmax=3, ymin=-2, ymax=2);
grid(pic=currentpicture,
     xmin=-3, xmax=3,
     ymin=-2, ymax=2,
     xStep=1, xstep=.1,
     yStep=1, ystep=.1,
     pTick=.8red, ptick=.8green,
     above=false);
cartesianaxis(pic=currentpicture,
              Lx=Label(scale(2)*"$x$",align=NW),
              Ly=Label("$y$",align=SE),
              xmin=-3, xmax=3,
              ymin=-2, ymax=2,
              extrawidth=5, extraheight=5,
              p=currentpen,
              xticks=Ticks("%",pTick=1mm+yellow, ptick=grey),
              yticks=NoTicks,
              viewxaxis=true,
              viewyaxis=false,
              above=true,
              arrow=Arrow);
labeloIJ(pic=currentpicture,
         Lo=Label("$O$",NoFill),
         LI=Label("$I$",white,Fill(black)),
         LJ=Label(" "),
         diro=NE, dirI=N, dirJ=E,
         p=blue,
         filltype=NoFill,
         marker=dot(2mm+red));

Étiquettes : , ,


Unofficial package graph_pi.asy – fig0030

Category: Asymptote,graph_pi.asy,Unofficial packagesPh. Ivaldi @ 7 h 50 min

Figure 0003
(Compiled with Asymptote version 2.14svn-r5318)
    
import graph_pi;
size(200,0);
graphicrules(xmin=-1, xmax=4, ymin=-1, ymax=3);

grid(xstep=0,ystep=0);

cartesianaxis(xticks=Ticks(Label(Fill(white)), NoZero, ptick=invisible),
              yticks=Ticks(Label(Fill(white)), NoZero, ptick=invisible));

labelx("$O$",0,SW);

shipout(bbox(Fill(white)));

Étiquettes : , ,


Unofficial package graph_pi.asy – fig0040

Category: Asymptote,graph_pi.asy,Unofficial packagesPh. Ivaldi @ 8 h 50 min

Figure 0004
(Compiled with Asymptote version 2.14svn-r5318)
    
import graph_pi;

graphicrules(xunit=2cm, yunit=1.5cm, xmin=-3, xmax=2, ymin=-2, ymax=2);
add(millimeterpaper(p=3bp+orange),(0,0));
cartesianaxis();
labelx(Label("$1$",UnFill), 1);
labely(Label("$1$",UnFill), 1);
labelx("$O$",0,SW);
dot((0,0));

Étiquettes : ,


Unofficial package graph_pi.asy – fig0050

Category: Asymptote,graph_pi.asy,Unofficial packagesPh. Ivaldi @ 9 h 50 min

Figure 0005
(Compiled with Asymptote version 2.14svn-r5318)
    
import graph_pi;

graphicrules(xunit=2cm, yunit=1.5cm, xmin=-3, xmax=2, ymin=-2, ymax=2);
add(millimeterpaper(pic=currentpicture, O=(0,0),
                    xmin=-2.5, xmax=1.5,
                    ymin=-1.5, ymax=1.5,
                    p=3bp+orange),
    (0,0));
cartesianaxis();
labelx(Label("$1$",UnFill), 1);
labely(Label("$1$",UnFill), 1);
labelx("$O$",0,SW);
dot((0,0));

Étiquettes : ,


Unofficial package graph_pi.asy – fig0060

Category: Asymptote,graph_pi.asy,Unofficial packagesPh. Ivaldi @ 10 h 50 min

Figure 0006
(Compiled with Asymptote version 2.14svn-r5318)
    
import graph_pi;
import patterns;

graphicrules(xunit=2.5cm,yunit=1.5cm, xmin=-1, xmax=4, ymin=-1, ymax=5,
             crop=Crop);

// Définition des fonctions f et g :
real f(real x) {return 4x-x^2+4/(x^2+1)^2;}
real g(real x) {return x-1+4/(x^2+1)^2;}

// Tracé des courbes :
path Cf=graph(f,n=700);
path Cg=graph(g,n=700);
draw(Cf,linewidth(1bp));
draw(Cg,linewidth(1bp));
crop(currentpicture);

// La grille.
grid();
// Les axes.
cartesianaxis(xticks=Ticks(NoZero,ptick=grey),
              yticks=Ticks(NoZero,ptick=grey),arrow=None);
labeloij(UnFill);

label("$\mathscr{C}_f$",(2.25,f(2.25)),2N);
label("$\mathscr{C}_f$",(2.25,g(2.25)),2S);

// Les hachures.
path vline=(1,-1)--(1,5);
add("hachure",hatch(3mm));
fill(buildcycle(vline,graph(f,1,4),graph(g,1,4)),pattern("hachure"));

Étiquettes : , ,


Unofficial package graph_pi.asy – fig0070

Category: Asymptote,graph_pi.asy,Unofficial packagesPh. Ivaldi @ 11 h 50 min

Figure 0007
(Compiled with Asymptote version 2.14svn-r5318)
    
import graph_pi;

graphicrules(xunit=1cm, yunit=2cm,
             xmin=-2pi, xmax=2pi, ymin=-1, ymax=1);

yaxis("y",LeftRight ,
      Ticks(labelfrac,Step=.5,step=.25, ptick=grey, extend=true));

xaxis("$\theta$",BottomTop,
      Ticks(labelfrac(factor=pi,symbol="\pi",symbolin=false),
            Step=pi/2, step=pi/4, ptick=grey, extend=true));

draw(graph(new real(real x){return sin(x);},-2pi,2pi));
draw(graph(new real(real x){return cos(x);},-2pi,2pi), .8red);

Étiquettes : , ,


Unofficial package graph_pi.asy – fig0080

Category: Asymptote,graph_pi.asy,Unofficial packagesPh. Ivaldi @ 12 h 50 min

Figure 0008
(Compiled with Asymptote version 2.14svn-r5318)
    
import graph_pi;

graphicrules(xunit=1cm, yunit=3cm,
             xmin=-2pi, xmax=2pi, ymin=-1, ymax=1);

grid(xStep=pi/2, xstep=pi/4, yStep=.5, ystep=.25);

cartesianaxis(xticks=Ticks(Label(Fill(white)),
                           labelfrac(factor=pi,symbol="\pi",symbolin=true,
                                     zero=false),Step=pi/2, step=pi/4, ptick=grey),
              yticks=Ticks(Label(Fill(white)),
                           labelfrac(zero=false),Step=.5,step=.25, ptick=grey), Arrow);

dot("$O$",(0,0),2SW);

shipout(bbox(Fill(white)));

Étiquettes : , ,


Unofficial package graph_pi.asy – fig0090

Category: Asymptote,graph_pi.asy,Unofficial packagesPh. Ivaldi @ 13 h 50 min

Figure 0009
(Compiled with Asymptote version 2.14svn-r5318)
    
import graph_pi;

real f(real x){return -.8x+3;}

graphicrules(unit=1cm,
             xmin=-2, xmax=6, ymin=-2, ymax=6);

draw(graph(f));
draw(graph(new real(real x){return x;}), grey);
cartesianaxis();
draw(recursivegraph(f,-1.8,n=7),.8red);

Étiquettes : ,


Unofficial package graph_pi.asy – fig0100

Category: Asymptote,graph_pi.asy,Unofficial packagesPh. Ivaldi @ 14 h 50 min

Figure 0010
(Compiled with Asymptote version 2.14svn-r5318)
    
import graph_pi;

real f(real x){return -.8x+3;}

graphicrules(unit=1cm,
             xmin=-2, xmax=6, ymin=-2, ymax=6);

draw(graph(f));
draw(graph(new real(real x){return x;}), grey);
cartesianaxis();
draw(recursivegraph(f,-1.8,n=7),
     //This is the default options
     recursiveoption(L="u",
                    labelbegin=true,
                    labelend=true,
                    labelinner=true,
                    labelalternate=false,
                    format="",
                    labelplace=onX,
                    px=nullpen,
                    py=nullpen,
                    startonyaxis=false,
                    circuitarrow=None,
                    automarker=marker(cross(4)),
                    xaxismarker=nomarker,
                    yaxismarker=nomarker,
                    xmarker=nomarker,
                    fmarker=nomarker),
     .8red);

Étiquettes : ,